This notebook calculates the superfluid density as a function of temperature and scattering rate 1/τ
Following Dutta, et al., arXiv:2101.06697
Here τ is the inverse of the broadening of the electron spectral density.  It acts like a momentum relaxation time for the quasiparticles, perhaps?

hbar=6.5821×10^(-16)   (* hbar in eV-s *)

kB=8.617333262×10^(-5)  (* kB in eV/K *)

Δ[Δ0_,t_] := Δ0*y/.FindRoot[ y == Tanh[y/t],{y,0.5} ][[1]]  (* Simple BCS gap temperature dependence *)

Plot[Δ[1,t], {t,.001,0.999}, PlotRange ->{ {0,1}, {0,1}}, PlotPoints -> 100]

nsbyn[T_,τ_,Tc_,Δ0_]:= π Δ[1,T/Tc] (Δ0 τ/hbar) Tanh[(Δ0/(2 kB Tc))  Δ[1,T/Tc] /(T/Tc)]-Δ[1,T/Tc] ^2 (1/Δ0) NIntegrate[Tanh[(Δ0/(2 kB Tc))  (ϵ/Δ0) /(T/Tc)]/((Sqrt[(ϵ/Δ0)^2 -Δ[1,T/Tc]^2]) ((ϵ/Δ0)^2-Δ[1,T/Tc]^2 +(1/(4 (Δ0 τ/hbar)^2)))),{ϵ,Δ0 Δ[1,T/Tc],∞}]   (* This is Eq. (11) of arXiv:2101.06697.   WARNING: Energies are in eV, NOT Joules! *)

nsbyn[1,10^(-12),9.2,1.5*10^(-3)]

1.5*10^(-3)*10^(-12)/hbar

Plot[nsbyn[T,10^(-12),9.2,1.5*10^(-3)], {T,0,9.19}]

Plot[nsbyn[T,10^(-11),9.2,1.5*10^(-3)], {T,0,9.19}]

LogLogPlot[nsbyn[10^(-3),τ,9.2,1.5*10^(-3)], {τ,10^(-16), 10^(-9)}]   (* This is basically n_s/n vs. Δ0 τ/ℏ in Fig. 1 of the paper *)

1.5*10^(-3)*0.43885*10^(-12)/hbar

Plot[{nsbyn[T,0.43885*10^(-12),9.2,1.5*10^(-3)],nsbyn[T,10*0.43885*10^(-12),9.2,1.5*10^(-3)], nsbyn[T,100*0.43885*10^(-12),9.2,1.5*10^(-3)], nsbyn[T,0.1*0.43885*10^(-12),9.2,1.5*10^(-3)], nsbyn[T,0.01*0.43885*10^(-12),9.2,1.5*10^(-3)], nsbyn[T,0.001*0.43885*10^(-12),9.2,1.5*10^(-3)]}, {T,0,9.19}]   (* This is essentially Fig. 2 of the paper *)

Take the London penetration depth to be the temperature independent quantity: λ_L = (Sqrt[(m/(μ0 n e^2))])
The the temperature dependent magnetic penetration depth of a superconductor to be λ(T, τ) = (Sqrt[(m/(μ0 ns(T, τ) e^2))]) 
Hence λ(T, τ)/λ_L = (Sqrt[(n/( ns(T, τ) ))])

λofTandτByλL[T_,τ_,Tc_,Δ0_]:= (Sqrt[1/nsbyn[T,τ,Tc,Δ0]])   (* This is the penetration depth at finite T and scattering time τ, normalized to the temperature-independent London penetration depth λ_L *)

λofTandτByλL[1,10^(-12),9.2,1.5*10^(-3)]

Plot[λofTandτByλL[T,10^(-13),9.2,1.5*10^(-3)], {T,0,9.19}]

Next step: Add information about the total electron carrier density n and electron mass m, to get the absolute value of the magnetic penetration depth for a given temperature T and scattering time τ